QT += core quick widgets dbus sql

# The following define makes your compiler emit warnings if you use
# any feature of Qt which as been marked deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS

# You can also make your code fail to compile if you use deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

SOURCES += \
    src/file.cpp \
    src/librarydb.cpp \
    src/main.cpp \
    src/mpris.cpp \
    src/mprisadaptor.cpp \
    src/mprisplayer.cpp \
    src/screen.cpp \
    src/thumbnailprovider.cpp \
    src/mpvaudio.cpp

HEADERS += \
    src/file.h \
    src/librarydb.h \
    src/mpris.h \
    src/mprisadaptor.h \
    src/mprisplayer.h \
    src/screen.h \
    src/thumbnailprovider.h \
    src/mpvaudio.h

CONFIG += c++20 link_pkgconfig

PKGCONFIG += mpv
#PKGCONFIG += KF6KIOCore KF6KIOGui
LIBS += -lKF6KIOCore -lKF6KIOGui -lKF6CoreAddons
INCLUDEPATH += /usr/include/KF6/KIOGui /usr/include/KF6/KIO /usr/include/KF6/KIOCore /usr/include/KF6/KCoreAddons

# Additional import path used to resolve QML modules in Qt Creator's code model
QML_IMPORT_PATH =

# Additional import path used to resolve QML modules just for Qt Quick Designer
QML_DESIGNER_IMPORT_PATH =

DISTFILES = \
    $$files(qml/*, true)

resources.prefix = /
resources.base = $$PWD
resources.files = \
    $$files(qml/*, true)

RESOURCES += resources

isEmpty(PREFIX) {
    PREFIX = /usr/local
}

isEmpty(BINDIR) {
    BINDIR = $$PREFIX/bin
}
isEmpty(DATADIR) {
    DATADIR = $$PREFIX/share
}
isEmpty(APPDIR) {
    APPDIR = $$DATADIR/applications
}
isEmpty(ICONDIR) {
    ICONDIR = $$DATADIR/icons/hicolor/512x512/apps
}

# ---- binary ----
target.path = $$BINDIR
INSTALLS += target

# ---- desktop file ----
desktop.files = Audiobooks.desktop
desktop.path = $$APPDIR
INSTALLS += desktop

# ---- icon ----
icon.files = Audiobooks.png
icon.path = $$ICONDIR
INSTALLS += icon